net-im/gajim: initial import

yeah, it's just gajim from gentoo but with version bumped up. i know.

4 files changed, 151 insertions, 0 deletions

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
new file mode 100644
index 0000000..5b7ab55
--- /dev/null
+++ b/net-im/gajim/Manifest
@@ -0,0 +1 @@
+DIST gajim-1.4.5.tar.gz 7167761 BLAKE2B 1c49f8eef8284b20beee933fda519729ff2007f8fb988ed900ba47531b7538046f7093aa142810f3b6686323f8b802df23c26b3065e62a980406da77928f7aee SHA512 bce88fc20f0c0571116e9145af222efab67b82184a87f40ddaba5f802cf5034caa1ea0feb89f518332cd5bd6a1e82ec1ca15199966e57aaf50701998c3a5edd8
diff --git a/net-im/gajim/gajim-1.4.5.ebuild b/net-im/gajim/gajim-1.4.5.ebuild
new file mode 100644
index 0000000..bd2e4ff
--- /dev/null
+++ b/net-im/gajim/gajim-1.4.5.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_REQ_USE="sqlite,xml"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="https://gajim.org/"
+SRC_URI="https://gajim.org/downloads/$(ver_cut 1-2)/${P/_p/-}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+crypt geolocation jingle omemo remote rst +spell upnp +webp"
+S="${WORKDIR}/${P%_p2}"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo(+)]
+	>=x11-libs/gtk+-3.22:3[introspection]
+	x11-libs/gtksourceview:4"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/precis-i18n[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		>=dev-python/python-nbxmpp-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/python-nbxmpp-4.0.0[${PYTHON_USEDEP}]
+		x11-libs/libXScrnSaver
+		app-crypt/libsecret[crypt,introspection]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		>=dev-python/secretstorage-3.1.1[${PYTHON_USEDEP}]
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		net-libs/libsoup[introspection]
+		media-libs/gsound[introspection]
+		crypt? (
+			dev-python/pycryptodome[${PYTHON_USEDEP}]
+			>=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+		geolocation? ( app-misc/geoclue[introspection] )
+		jingle? (
+			net-libs/farstream:0.2[introspection]
+			media-libs/gstreamer:1.0[introspection]
+			media-libs/gst-plugins-base:1.0[introspection]
+			media-libs/gst-plugins-ugly:1.0
+			media-plugins/gst-plugins-gtk
+		)
+		omemo? (
+			dev-python/python-axolotl[${PYTHON_USEDEP}]
+			dev-python/qrcode[${PYTHON_USEDEP}]
+			dev-python/cryptography[${PYTHON_USEDEP}]
+		)
+		remote? (
+			>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+			sys-apps/dbus[X]
+		)
+		rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+		spell? (
+			app-text/gspell[introspection]
+			app-text/hunspell
+		)
+		upnp? ( net-libs/gupnp-igd[introspection] )
+		webp? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	')"
+
+src_install() {
+	distutils-r1_src_install
+
+	# avoid precompressed man pages
+	rm -r "${D}/usr/share/man"
+	doman data/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+# Tests are unfortunately regularly broken
+RESTRICT="test"
diff --git a/net-im/gajim/metadata.xml b/net-im/gajim/metadata.xml
new file mode 100644
index 0000000..ad0044c
--- /dev/null
+++ b/net-im/gajim/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>la-ninpre</name>
+    <email>aaoth@aaoth.xyz</email>
+  </maintainer>
+  <use>
+    <flag name="crypt">End to end encryption and GPG encryption</flag>
+    <flag name="geolocation">Sharing your location</flag>
+    <flag name="jingle">Audio and video calls</flag>
+    <flag name="remote">Controling Gajim instance from command line with gajim-remote</flag>
+    <flag name="rst">Generating XHTML output from RST code</flag>
+    <flag name="spell">Spellchecking of composed messages</flag>
+    <flag name="upnp">Ability to request your router to forward port for file transfer</flag>
+    <flag name="webp">Support WebP avatars</flag>
+    <flag name="omemo">Install dependencies for OMEMO encryption plugin</flag>
+  </use>
+</pkgmetadata>
diff --git a/net-im/metadata.xml b/net-im/metadata.xml
new file mode 100644
index 0000000..55f0a26
--- /dev/null
+++ b/net-im/metadata.xml
@@ -0,0 +1,34 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE catmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<catmetadata>
+	<longdescription lang="en">
+		The net-im category contains instant messaging software.
+	</longdescription>
+	<longdescription lang="de">
+		Die Kategorie net-im enthält Software für Instant Messaging.
+	</longdescription>
+	<longdescription lang="es">
+		La categoría net-im contiene programas de mensajería instantánea.
+	</longdescription>
+	<longdescription lang="ja">
+		net-imカテゴリーにはインスタント・メッセージのソフトウェアが含まれています。
+	</longdescription>
+	<longdescription lang="nl">
+		De net-im categorie bevat applicaties voor instant messaging.
+	</longdescription>
+	<longdescription lang="sk">
+		Kategória net-im obsahuje aplikácie pre instant messaging.
+	</longdescription>
+	<longdescription lang="vi">
+		Nhóm net-im chứa các phần mềm nhắn tin.
+	</longdescription>
+	<longdescription lang="it">
+		La categoria net-im contiene programmi per i messaggi istantanei.
+	</longdescription>
+	<longdescription lang="pt">
+		A categoria net-im contém programas para mensagens instantâneas.
+	</longdescription>
+	<longdescription lang="pl">
+		Kategoria net-im zawiera komunikatory internetowe.
+	</longdescription>
+</catmetadata>