@@ -0,0 +1,1 @@
+DIST libadwaita-1.2_rc.tar.xz 2953620 BLAKE2B 786a581e6ef2278c7790090b7dceb302f5457ec4394dddf964b5bd71a26bef995bda528ef18344bd11f025d0789c31780c146634fc54d1320fd3cc5d11d3883a SHA512 d0191f775c584b4e28c88bc9ceb7a9267487f78b9e10e78a6eb984c6961f81e9fa8b524ee233e1d95c0446aabb16c9ae05271d3d2be379b5806044412df0d37e

@@ -0,0 +1,71 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+VALA_MIN_API_VERSION="0.52"
+inherit gnome.org meson python-any-r1 vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME applications"
+HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
+
+MY_PV="$(ver_rs 2 .)"
+
+SRC_URI="mirror://gnome/sources/${GNOME_ORG_MODULE}/$(ver_cut 1-2)/${GNOME_ORG_MODULE}-${MY_PV}.tar.${GNOME_TARBALL_SUFFIX} -> ${P}.tar.${GNOME_TARBALL_SUFFIX}"
+
+S="${WORKDIR}/${GNOME_ORG_MODULE}-${MY_PV}"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+IUSE="+introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.66:2
+	>=gui-libs/gtk-4.5.0:4[introspection?]
+	dev-libs/fribidi
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	vala? ( $(vala_depend) )
+	>=dev-util/meson-0.59.0
+	dev-util/glib-utils
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		# Never use gi-docgen subproject
+		--wrap-mode nofallback
+
+		-Dprofiling=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		-Dgtk_doc=false # we ship pregenerated docs
+		$(meson_use test tests)
+		-Dexamples=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test --timeout-multiplier 2
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/gtk-doc/html
+	# This will install libadwaita API docs unconditionally, but this is intentional
+	doins -r "${S}"/doc/libadwaita-1
+}

@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="person">
+	<email>aaoth@aaoth.xyz</email>
+	<name>la ninpre</name>
+</maintainer>
+</pkgmetadata>