1# Copyright 2022 Gentoo Authors
 2# Distributed under the terms of the GNU General Public License v2
 3
 4EAPI=8
 5PYTHON_COMPAT=( python3_{8..11} )
 6VALA_MIN_API_VERSION="0.52"
 7inherit gnome.org meson python-any-r1 vala virtualx
 8
 9DESCRIPTION="Building blocks for modern adaptive GNOME applications"
10HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
11
12MY_PV="$(ver_rs 2 .)"
13
14SRC_URI="mirror://gnome/sources/${GNOME_ORG_MODULE}/$(ver_cut 1-2)/${GNOME_ORG_MODULE}-${MY_PV}.tar.${GNOME_TARBALL_SUFFIX} -> ${P}.tar.${GNOME_TARBALL_SUFFIX}"
15
16S="${WORKDIR}/${GNOME_ORG_MODULE}-${MY_PV}"
17
18LICENSE="LGPL-2.1+"
19SLOT="1"
20IUSE="+introspection test +vala"
21REQUIRED_USE="vala? ( introspection )"
22
23KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
24
25DEPEND="
26	>=dev-libs/glib-2.66:2
27	>=gui-libs/gtk-4.5.0:4[introspection?]
28	dev-libs/fribidi
29	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
30"
31RDEPEND="${DEPEND}"
32BDEPEND="
33	${PYTHON_DEPS}
34	vala? ( $(vala_depend) )
35	>=dev-util/meson-0.59.0
36	dev-util/glib-utils
37	sys-devel/gettext
38	virtual/pkgconfig
39"
40
41src_prepare() {
42	default
43	use vala && vala_setup
44}
45
46src_configure() {
47	local emesonargs=(
48		# Never use gi-docgen subproject
49		--wrap-mode nofallback
50
51		-Dprofiling=false
52		$(meson_feature introspection)
53		$(meson_use vala vapi)
54		-Dgtk_doc=false # we ship pregenerated docs
55		$(meson_use test tests)
56		-Dexamples=false
57	)
58	meson_src_configure
59}
60
61src_test() {
62	virtx meson_src_test --timeout-multiplier 2
63}
64
65src_install() {
66	meson_src_install
67
68	insinto /usr/share/gtk-doc/html
69	# This will install libadwaita API docs unconditionally, but this is intentional
70	doins -r "${S}"/doc/libadwaita-1
71}